;; | -----------------------------------------------------------------------------
;; | TX_ExtractXML 
;; | -----------------------------------------------------------------------------
;; | Function : Reads an XML file and extracts a complete section info
;; | Argument : 'Lst'      - XML file list
;; |            'Section'  - Section Name to read
;; |            'Multiple' - Read Multiple sections or not (T or nil) 
;; | Return   :"
;; | Update   : March 12, 2009
;; | e-mail   : rakesh.rao@4d-technologies.com
;; | Web      : www.4d-technologies.com
;; | -----------------------------------------------------------------------------


(defun TX_ExtractXML ( Lst Section Multiple / itm len len1 cnt More tmp Found Comment
 _SectionSt _SectionStP _SectionEn SectionLst )

(setq
	len           (length Lst)
	tmp           (strcat " of " (itoa len))
	cnt           0
	More          T
	Found         nil
	Comment       nil
	_SectionSt    (strcase Section)
	_SectionStP   (strcat (substr _SectionSt 1 (1- (strlen _SectionSt))) " " )	; Part of SectionSt, without the '>' but with an trailing space
	_SectionEn    (strcat "</" (substr _SectionSt 2))
	SectionLstBig '()
	SectionLst    '()
)

(if #Verbose
	(princ "\n")
)

(while More
	(setq
		itm  (ST_Trim (nth cnt Lst))
		len1 (strlen itm)
		cnt  (1+ cnt)
	)

	(if #Verbose
		(princ (strcat "\rParsing XML file..." (itoa cnt) tmp))
	)

	(if (>= len1 4)
	(progn
		(if (= (substr itm 1 4) "<!--")
			(setq Comment T)
		)
	))

	(if (not Comment)
	(progn
		(setq _itm (strcase itm))
		(cond
			((or
				(ST_FindPattern _itm _SectionSt)
				(ST_FindPattern _itm _SectionStP)
			)
				(setq
					SectionLst   (cons itm SectionLst)
					SectionFound T
				)
			)
			((ST_FindPattern _itm _SectionEn)
				(if SectionLst
				(progn
					(setq
						SectionLst    (cons itm SectionLst)
						SectionLst    (reverse SectionLst)
						SectionLstBig (append SectionLstBig (list SectionLst))
						SectionLst    '()
					)
					(if (not Multiple)
						(setq More nil)
					)
				))
				(setq SectionFound nil)
			)
			(T
				(if SectionFound
					(setq SectionLst (cons itm SectionLst))
				)
			)
		)
	)
	(progn
		(if (>= len1 3)
		(progn
			(if (= (substr itm 1 3) "-->")
				(setq Comment nil)
			)
		))
	))

	(if (= cnt len)
	(progn
		(if SectionLst
		(setq
			SectionLst    (cons itm SectionLst)
			SectionLst    (reverse SectionLst)
			SectionLstBig (append SectionLstBig (list SectionLst))
		))
		(setq More nil)
	))
)
SectionLstBig
)