;; | ----------------------------------------------------------------------------
;; | ST_StrTokNoWhite
;; | ----------------------------------------------------------------------------
;; | Function : Splits up a string into a list of tokens delimited by a list of
;; |            delimiters and does not return any white spaces between delimiters
;; | Argument : [lstr]     - The String
;; |            [DelimLst] - The list of possible delimiters
;; | Return   : A list of delimited strings
;; | Updated  : July 3, 2004
;; | e-mail   : rakesh.rao@4d-technologies.com 
;; | Web      : www.4d-technologies.com
;; | ----------------------------------------------------------------------------


(defun ST_StrTokNoWhite( lstr DelimLst / cnt len Lst str Char StrAdded)
(setq
	len      (strlen lstr)
	cnt      1
	Lst     '()
	str      ""
	StrAdded nil
)

(repeat len
	(setq
		Char (substr lstr cnt 1)
		cnt  (1+ cnt)
	)

	(if (not (member Char DelimLst))
	(setq
		str      (strcat str Char)
		StrAdded nil
	)
	(progn
		(if (not StrAdded)
		(progn
			(if (/= str "")
				(setq
					Lst      (append Lst (list str))
					StrAdded T
					str      ""
				)
			)
		))
	))
)
(if (/= str "")
	(setq Lst (append Lst (list str)))
)
 Lst
)