;; | ----------------------------------------------------------------------------
;; | PL_GetBulgeLst
;; | ----------------------------------------------------------------------------
;; | Function : Returns the bulge list of an arced polyline
;; | Argument : 'ename' - Polyline object name
;; | Returns  : The list of all bulge values at each vertex
;; | Updated  : September 16, 2008
;; | e-mail   : rakesh.rao@4d-technologies.com 
;; | Web      : www.4d-technologies.com
;; | ----------------------------------------------------------------------------


(defun PL_GetBulgeLst( ename / flag en entl VxEntl BlgLst Blg )

(setq
	BlgLst '()
	entl (entget ename)
	en (LI_item 0 entl)
)
(cond
	((= en "POLYLINE")
		(setq VxEntl (cdr (PL_GetVxEntl ename)))
		(foreach entl VxEntl
			(setq flag (LI_item 70 entl))
			(if (and (zerop (logand flag 1)) (zerop (logand flag 2)) (zerop (logand flag 8)))
			(progn
				(setq Blg (LI_item 42 entl))
				(if (not Blg)
					(setq Blg 0.0)
				)
				(setq BlgLst (cons Blg BlgLst))
			))
		)
		(setq BlgLst (reverse BlgLst))
	)
	((= en "LWPOLYLINE")
		(setq BlgLst (LI_mitem 42 entl))
	)
)
BlgLst
)