;; | ----------------------------------------------------------------------------
;; | PL_DrawLeaders
;; | ----------------------------------------------------------------------------
;; | Function : Draws Leaders along each segment of the polyline, thus showing
;; |            the direction of flow of the polyline.
;; | Arguments:
;; |            'vlist'  - List of coordinates of the polyline
;; |            'Closed' - Flag to indicate if the polyline is closed or not
;; | Action   : Returns a selection set of all the leader objects created
;; | Updated  : November 11, 2000
;; | e-mail   : rakesh.rao@4d-technologies.com 
;; | Web      : www.4d-technologies.com
;; | ----------------------------------------------------------------------------


(defun PL_DrawLeaders ( vlist Closed / pt1 pt2 Seg SegLst ss OS MidPt )

(setq OS (getvar "OSMODE"))
(setvar "OSMODE" 0)
 
(setq
	SegLst (GE_GetSegmentPoints vlist Closed)
	ss     (ssadd)
)
(foreach Seg SegLst
	(setq
		pt1   (nth 0 Seg)
		pt2   (nth 1 Seg)
		MidPt (MI_MidPoint pt1 pt2)
	)
	(command "._Leader" MidPt pt1 "" "" "_None")
	(ssadd (entlast) ss)
	(command "._Line" MidPt pt2 "")
	(ssadd (entlast) ss)
)
(setvar "OSMODE" OS)
(if (> (sslength ss) 0) ss nil)
)