;; | ---------------------------------------------------------------------------
;; | MI_CurveSlope@Pt
;; | ---------------------------------------------------------------------------
;; | Function  : Returns the slope of the curve as the specified point
;; | Arguments : 'ename' - Curve object name
;; |             'pt'    - Point at which slope is to be measured
;; | Returns  : None
;; | Updated  : January 31, 2007
;; | e-mail   : rakesh.rao@4d-technologies.com
;; | Web      : www.4d-technologies.com
;; | ---------------------------------------------------------------------------


(defun MI_CurveSlope@Pt ( ename pt / ang oname param fd pt1 )

(setq
	ang   nil
	oname (vlax-ename->vla-object ename)
)

(setq pt (vlax-curve-getClosestPointTo oname pt))

(if pt
(progn
	(setq param (vlax-curve-getParamAtPoint oname pt))
	(if param
	(setq
		fd  (vlax-curve-getFirstDeriv oname param)
		pt1 (MI_Shift pt (car fd) (cadr fd) (caddr fd))
		ang (angle pt pt1)
	))
))
(vlax-release-object oname)
(if ang (list ang pt) nil)
)