;; | ----------------------------------------------------------------------------
;; | DL_Output_Ctrl_dlg
;; | ----------------------------------------------------------------------------
;; | Function    : Output Control Dialog for specifying Destination layer and
;; |               object handling.
;; | Arguments   : 'CtrlLst' - Control List denotes how the output objects have to
;; |               handled.
;; |               (list {"Source" / "Current"} {"Yes" / "No"})
;; | Author      : Rakesh Rao, (C) Four Dimension Technologies, Bangalore
;; | Updated     : July 19, 1999
;; | e-mail   : rakesh.rao@4d-technologies.com 
;; | Web      : www.4d-technologies.com
;; | ----------------------------------------------------------------------------


(defun DL_Output_Ctrl_dlg ( CtrlLst / LyrPlace DelOrg LyrName
 RetVal _RetVal Lyr )

(setq #OutputCntrl CtrlLst)

(if (or
		#DevVersion
		(= #OperatingEnv "BricsCAD")
		(/= #ProductName "GeoTools")
	)
	(progn
		(setq #dcl_id2 (load_dialog #DclFile2))
		(if (not (new_dialog "output_ctrl_dlg" #dcl_id2))
			(exit)
		)
	)
	(progn
		(if (not (new_dialog "output_ctrl_dlg" #dcl_id))
			(exit)
		)
	)
)

(setq
	LyrPlace (nth 0 #OutputCntrl)
	DelOrg   (nth 1 #OutputCntrl)
	LyrName  (nth 2 #OutputCntrl)
)

(cond
	((= LyrPlace "Source")
		(set_tile "source" "1")
		(mode_tile "select_layer" 1)
		(mode_tile "layer_name" 1)
	)
	((= LyrPlace "Current")
		(set_tile "current" "1")
		(mode_tile "select_layer" 1)
		(mode_tile "layer_name" 1)
	)
	((= LyrPlace "Specify")
		(set_tile "specify" "1")
	)
)

(set_tile "del_org" (if (= DelOrg "Yes") "1" "0"))
(set_tile "layer_name" LyrName)

(action_tile "source"       "(DL_Disp_OCD)")
(action_tile "current"      "(DL_Disp_OCD)")
(action_tile "specify"      "(DL_Disp_OCD)")
(action_tile "del_org"      "(DL_Disp_OCD)")
(action_tile "layer_name"   "(DL_Disp_OCD)")
(action_tile "select_layer" "(DL_Disp_OCD)")
(action_tile "accept"       "(done_dialog 100)")
(action_tile "cancel"       "(done_dialog 99)")

(setq RetVal (start_dialog))

(if (= RetVal 100)
	(setq RetVal #OutputCntrl)
	(setq RetVal nil)
)

RetVal
)


(defun DL_Disp_OCD( / tmp )
(cond
	((= $key "del_org")
		(setq tmp (get_tile "del_org"))
		(if (= tmp "1")
			(setq tmp "Yes")
			(setq tmp "No")
		)
		(setq #OutputCntrl (LI_RepList #OutputCntrl 2 tmp))
	)
	((= $key "source")
		(setq #OutputCntrl (LI_RepList #OutputCntrl 1 "Source"))
		(mode_tile "select_layer" 1)
		(mode_tile "layer_name"   1)
	)
	((= $key "current")
		(setq #OutputCntrl (LI_RepList #OutputCntrl 1 "Current"))
		(mode_tile "select_layer" 1)
		(mode_tile "layer_name"   1)
	)
	((= $key "specify")
		(setq #OutputCntrl (LI_RepList #OutputCntrl 1 "Specify"))
		(mode_tile "select_layer" 0)
		(mode_tile "layer_name"   0)
	)
	((= $key "layer_name")
		(setq
			tmp          (DL_ProcTile1 $key (nth 2 #OutputCntrl) "String" "All" 0)
			#OutputCntrl (LI_RepList #OutputCntrl 3 tmp)
		)
	)
	((= $key "select_layer")
		(setq tmp (DL_SelectProperty (LA_GetAllLayers) (nth 2 #OutputCntrl) nil nil "Select layer"))
		(if tmp
		(progn
			(set_tile "layer_name" tmp)
			(setq #OutputCntrl (LI_RepList #OutputCntrl 3 tmp))
		))
	)
)
)